home *** CD-ROM | disk | FTP | other *** search
/ FishMarket 1.0 / FishMarket v1.0.iso / fishies / 126-150 / disk_130 / qman / mandel.asm < prev    next >
Assembly Source File  |  1992-05-06  |  5KB  |  109 lines
  1. ****************************************************************************
  2. *
  3. *         Draws  a Row of Pixels in Mandelbrot Set
  4. *
  5. *         C must set the following variables prior to call:
  6. * 
  7. *                xptr   :  pointer to table of x-values 
  8. *                imagc  :  imaginary part of current pixel row
  9. *                bp1-4  :  pointers to the four bit planes
  10. *  
  11. *         Integers are 2**26 times the actual values in the complex plane
  12. *
  13. ****************************************************************************
  14.  
  15.             XDEF        _mandel              This tells C about us
  16.             SECTION     text,code
  17.  
  18. _mandel     movem.l     d2-d7/a2-a6,-(a7)    save registers
  19. setup       moveq       #8,d4                bit within screen byte
  20.             move.l      #639,pixct           pixel counter for current row
  21.             move.l      _xptr,a5              
  22.             move.l      _imagc,d6
  23.             move.l      _bp1,a0              
  24.             move.l      _bp2,a1
  25.             move.l      _bp3,a2
  26.             move.l      _bp4,a3
  27.   
  28. xloop       move.l      (a5)+,d5             move next x-value into D5
  29.             moveq       #79,d3               set counter to 79
  30.             clr.l       d0                   zero out real_z
  31.             clr.l       d2                   zero out imag_z
  32.  
  33. repeat      moveq       #13,d7               number of bits to shift
  34.             asr.l       d7,d0                divide real_z by 2**13
  35.             asr.l       d7,d2                divide imag_z by 2**13
  36.  
  37.             move.l      d0,d1                real_z
  38.             sub.w       d2,d0                real_z - imag_z
  39.             add.w       d1,d1                2 * real_z
  40.             muls        d1,d2                2 * real_z * imag_z
  41.             sub.w       d0,d1                real_z + imag_z
  42.             muls        d1,d0                real_z**2 - imag_z**2
  43.            
  44.             add.l       d5,d0                add real_c to get new real_z
  45.             move.l      d0,d7                create temp copy of real_z
  46.             bpl         pos_1                if real_z positive, do nothing
  47.             neg.l       d7                   take absolute value of real_z
  48. pos_1       add.l       d6,d2                add imag_c to get new imag_z
  49.             move.l      d2,d1                load working copy of imag_z
  50.             bpl         pos_2                if imag_z positive, do nothing
  51.             neg.l       d1                   take absolute value of imag_z
  52. pos_2       add.l       d1,d7                d7 contains the norm of z
  53.             subq        #1,d3                decrement counter by 1
  54.             beq         poke                 if 120 iters, draw the pixel
  55.             subi.l      #200000000,d7        reduce the norm by 200 million 
  56.             bmi         repeat               if z not exploding, continue
  57.             addq        #1,d3                increment counter by 1
  58.             asr.l       #3,d3                color is 1/8 number of iters
  59.             addq        #3,d3                range 3 to 12
  60.  
  61. poke        tst.l       d4                   examine bit within byte
  62.             bne         plane1               if not bit zero, poke planes
  63.             moveq       #8,d4                reset to bit 8 (next will be 7)
  64.             lea         1(a0),a0             incr addr within 1st bit plane
  65.             lea         1(a1),a1                              2nd
  66.             lea         1(a2),a2                              3rd
  67.             lea         1(a3),a3                              4th
  68. plane1      subq.l      #1,d4                decrement bit within byte by 1
  69.  
  70. nomenus     btst        d4,(a0)              if we've hit a menu-- STOP!
  71.             bne         nomenus
  72.             btst        d4,(a1)
  73.             bne         nomenus
  74.             btst        d4,(a2)
  75.             bne         nomenus
  76.             btst        d4,(a3)
  77.             bne         nomenus
  78.  
  79.             btst        #0,d3                examine 1st bit of color
  80.             beq         plane2               if bit off, leave screen alone
  81.             bset        d4,(a0)              turn current bit on in plane
  82. plane2      btst        #1,d3              
  83.             beq         plane3
  84.             bset        d4,(a1)
  85. plane3      btst        #2,d3
  86.             beq         plane4
  87.             bset        d4,(a2)
  88. plane4      btst        #3,d3
  89.             beq         next_x
  90.             bset        d4,(a3)
  91. next_x      subi.l      #1,pixct             decrement x counter
  92.             bpl         xloop                if not done with row, continue
  93.  
  94.             add.l       #80,_bp1             advance to next display line
  95.             add.l       #80,_bp2
  96.             add.l       #80,_bp3
  97.             add.l       #80,_bp4
  98.  
  99.             movem.l     (a7)+,d2-d7/a2-a6    restore registers
  100.           
  101.             rts
  102.  
  103.             SECTION     udata,bss      
  104.             XREF        _xptr,_imagc
  105.             XREF        _bp1,_bp2,_bp3,_bp4
  106. pixct       DS.L        1
  107.             END
  108.  
  109.